use v5.30.0;

use strict;
use warnings;

use Test::Most tests => 6;

use DBI;
use DateTime;

use Peace::Model::Customer;

BEGIN {
    use_ok 'Peace::DAO::Customer';
}

{
    ## GIVEN
    my $sql = <<'EOF';
INSERT INTO customers (secret) VALUES (?) RETURNING uuid; 
EOF
    my $uuid         = 'hola';
    my $dbh          = DBI->connect( 'DBI:Mock:', '', '' );
    my $customer     = Peace::Model::Customer->new( secret => 'hola' );
    my $customer_dao = Peace::DAO::Customer->new( dbh => $dbh );

    $dbh->{mock_add_resultset} = {
        sql     => $sql,
        results => [ ['uuid'], [$uuid], ]
    };
    $sql = <<'EOF';
SELECT uuid, date_creation, secret, stripe_id FROM customer WHERE uuid = ?;
EOF
    $dbh->{mock_add_resultset} = {
        sql     => $sql,
        results => [ ['uuid', 'secret', 'date_creation', 'stripe_id'], [$uuid, 'hola', undef, undef] ],
    };
    ## WHEN
    $customer_dao->create( customer => $customer );

    ## THEN
    is $customer->uuid, $uuid, 'Customer id correctly set after user creation.';
}

{
    ## GIVEN
    my $dbh = DBI->connect( 'DBI:Mock:', '', '' );
    my $customer_dao = Peace::DAO::Customer->new( dbh => $dbh );
    my $sql = <<'EOF';
SELECT uuid, date_creation, secret, stripe_id FROM customer WHERE uuid = ?;
EOF
    my $uuid          = 'hola';
    my $date_creation = DateTime->now;
    my $secret        = 'hola';
    my $stripe_id     = undef;

    $dbh->{mock_add_resultset} = {
        sql     => $sql,
        results => [
            [ 'uuid', 'date_creation', 'secret', 'stripe_id' ],
            [ $uuid,  $date_creation,  $secret,  $stripe_id ],
        ]
    };

    ## WHEN
    my $customer = $customer_dao->recover_by_uuid( uuid => $uuid );

    ## THEN
    is $customer->uuid, $uuid, 'Uuid is recovered correctly';
    is $customer->date_creation, $date_creation,
      'Date creation is recovered correctly';
    is $customer->secret,    $secret,    'Secret is recovered correctly';
    is $customer->stripe_id, $stripe_id, 'Secret is recovered correctly';

}