Streamer: Don't send out stream events for blocked users.

lib/pleroma/web/streamer.ex

@@ -110,20 +110,26 @@ def handle_cast(m, state) do
 
   def push_to_socket(topics, topic, item) do
     Enum.each(topics[topic] || [], fn socket ->
-      json =
+      # Get the current user so we have up-to-date blocks etc.
-        %{
+      user = User.get_cached_by_ap_id(socket.assigns[:user].ap_id)
-          event: "update",
+      blocks = user.info["blocks"] || []
-          payload:
-            Pleroma.Web.MastodonAPI.StatusView.render(
-              "status.json",
-              activity: item,
-              for: socket.assigns[:user]
-            )
-            |> Jason.encode!()
-        }
-        |> Jason.encode!()
 
-      send(socket.transport_pid, {:text, json})
+      unless item.actor in blocks do
+        json =
+          %{
+            event: "update",
+            payload:
+              Pleroma.Web.MastodonAPI.StatusView.render(
+                "status.json",
+                activity: item,
+                for: user
+              )
+              |> Jason.encode!()
+          }
+          |> Jason.encode!()
+
+        send(socket.transport_pid, {:text, json})
+      end
     end)
   end
 

test/web/streamer_test.exs

@@ -0,0 +1,63 @@
+defmodule Pleroma.Web.StreamerTest do
+  use Pleroma.DataCase
+
+  alias Pleroma.Web.Streamer
+  alias Pleroma.User
+  alias Pleroma.Web.CommonAPI
+  import Pleroma.Factory
+
+  test "it sends to public" do
+    user = insert(:user)
+    other_user = insert(:user)
+
+    task =
+      Task.async(fn ->
+        assert_receive {:text, _}, 4_000
+      end)
+
+    fake_socket = %{
+      transport_pid: task.pid,
+      assigns: %{
+        user: user
+      }
+    }
+
+    {:ok, activity} = CommonAPI.post(other_user, %{"status" => "Test"})
+
+    topics = %{
+      "public" => [fake_socket]
+    }
+
+    Streamer.push_to_socket(topics, "public", activity)
+
+    Task.await(task)
+  end
+
+  test "it doesn't send to blocked users" do
+    user = insert(:user)
+    blocked_user = insert(:user)
+    {:ok, user} = User.block(user, blocked_user)
+
+    task =
+      Task.async(fn ->
+        refute_receive {:text, _}, 1_000
+      end)
+
+    fake_socket = %{
+      transport_pid: task.pid,
+      assigns: %{
+        user: user
+      }
+    }
+
+    {:ok, activity} = CommonAPI.post(blocked_user, %{"status" => "Test"})
+
+    topics = %{
+      "public" => [fake_socket]
+    }
+
+    Streamer.push_to_socket(topics, "public", activity)
+
+    Task.await(task)
+  end
+end