Adding new dependencies

2022-07-12 02:02:46 +02:00 · 2022-07-12 02:02:46 +02:00 · 08dc6bbe34
commit 08dc6bbe34
parent 12cd71fa5d
7 changed files with 790 additions and 1 deletions
--- a/app-arch/lzma-recuento/lzma-recuento-0.0.1.ebuild
+++ b/app-arch/lzma-recuento/lzma-recuento-0.0.1.ebuild
@ -0,0 +1,35 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson toolchain-funcs
+
+MY_P="lzma1900"
+DESCRIPTION="LZMA Stream Compressor from the SDK"
+HOMEPAGE="https://www.7-zip.org/sdk.html"
+SRC_URI="mirror://sourceforge/sevenzip/${MY_P}.7z -> ${P}.7z"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc"
+
+BDEPEND="app-arch/p7zip"
+
+S=${WORKDIR}
+
+src_configure() {
+	cp ${FILESDIR}/meson.build ${S}
+	rm -rf bin/*.sfx
+	find -name '*.ico' -exec cp -v "${FILESDIR}/recuento.ico" {} \; || die
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+}
+
+src_install() {
+	meson_src_install
+}
--- a/app-misc/recuento/recuento-0.0.1.ebuild
+++ b/app-misc/recuento/recuento-0.0.1.ebuild
@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 EAPI=8

-inherit meson xdg
+inherit meson xdg toolchain-funcs

 DESCRIPTION="A free software manga reader."
 HOMEPAGE="https://gitea.sergiotarxz.freemyip.com"
@ -16,6 +16,8 @@ KEYWORDS="~amd64"
 DEPEND="
 >=gui-libs/libadwaita-1.1.0
 >=dev-db/sqlite-3.38.0
+>=sys-libs/owlpath-0.0.1
+>=sys-libs/kbdus-0.0.1
 "

 RDEPEND="${DEPEND}"
@ -23,6 +25,7 @@ BDEPEND="
 virtual/pkgconfig
 >=dev-util/meson-0.60.3
 "
+CC+="$(tc-getCC) -mwindows"

 src_configure() {
 	VALAC=/usr/bin/valac-0.56 meson_src_configure
--- a/gui-libs/gtk/gtk-4.6.6.ebuild
+++ b/gui-libs/gtk/gtk-4.6.6.ebuild
@ -0,0 +1,211 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit gnome.org gnome2-utils meson optfeature python-any-r1 virtualx xdg
+
+DESCRIPTION="GTK is a multi-platform toolkit for creating graphical user interfaces"
+HOMEPAGE="https://www.gtk.org/ https://gitlab.gnome.org/GNOME/gtk/"
+
+LICENSE="LGPL-2+"
+SLOT="4"
+IUSE="aqua broadway colord cups examples ffmpeg gstreamer +introspection sysprof test vulkan wayland +X cpu_flags_x86_f16c"
+REQUIRED_USE="
+	test? ( introspection )
+"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/fribidi-0.19.7
+	>=dev-libs/glib-2.66.0:2
+	>=media-libs/graphene-1.9.1[introspection?]
+	>=x11-libs/cairo-1.14[aqua?,glib,svg,X?]
+	>=x11-libs/gdk-pixbuf-2.30:2[introspection?]
+	>=x11-libs/pango-1.50.0[introspection?]
+	media-libs/libpng:0=
+	media-libs/tiff:0=
+	>=media-libs/libepoxy-1.4[X(+)?]
+	media-libs/libjpeg-turbo:0=
+	>=media-libs/harfbuzz-2.1.0:=
+	x11-misc/shared-mime-info
+
+	colord? ( >=x11-misc/colord-0.1.9:0= )
+	cups? ( >=net-print/cups-2.0 )
+	ffmpeg? ( media-video/ffmpeg )
+	gstreamer? (
+		>=media-libs/gst-plugins-bad-1.12.3
+		>=media-libs/gst-plugins-base-1.12.3[opengl]
+	)
+	introspection? ( >=dev-libs/gobject-introspection-1.39:= )
+	vulkan? ( media-libs/vulkan-loader:= )
+	wayland? (
+		>=dev-libs/wayland-1.20.0
+		>=dev-libs/wayland-protocols-1.23
+		media-libs/mesa[wayland]
+		>=x11-libs/libxkbcommon-0.2
+	)
+	X? (
+		>=app-accessibility/at-spi2-atk-2.5.3
+		media-libs/fontconfig
+		media-libs/mesa[X(+)]
+		x11-libs/libX11
+		>=x11-libs/libXi-1.8
+		x11-libs/libXext
+		>=x11-libs/libXrandr-1.5
+		x11-libs/libXcursor
+		x11-libs/libXfixes
+		x11-libs/libXdamage
+		x11-libs/libXinerama
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+	X? ( x11-base/xorg-proto )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/gtk-update-icon-cache-3
+"
+# librsvg for svg icons (PDEPEND to avoid circular dep), bug #547710
+PDEPEND="
+	gnome-base/librsvg
+	>=x11-themes/adwaita-icon-theme-3.14
+"
+BDEPEND="
+	dev-libs/gobject-introspection-common
+	introspection? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep '
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+		')
+	)
+	dev-python/docutils
+	>=dev-util/gdbus-codegen-2.48
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+	test? (
+		dev-libs/glib:2
+		wayland? ( dev-libs/weston[headless] )
+	)
+"
+
+python_check_deps() {
+	python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" || return
+}
+
+pkg_setup() {
+	use introspection && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# dev-python/docutils installs rst2man.py, not rst2man
+	sed -i -e "s/'rst2man'/'rst2man.py'/" docs/reference/gtk/meson.build || die
+	# Nothing should use gtk4-update-icon-cache and an unversioned one is shipped by dev-util/gtk-update-icon-cache
+	sed -i -e '/gtk4-update-icon-cache/d' tools/meson.build || die
+	# Workaround RWX ELF sections, https://gitlab.gnome.org/GNOME/gtk/-/issues/4598
+	sed -i -e 's/^ld =.*/ld = disabler()/g' gtk/meson.build demos/gtk-demo/meson.build demos/widget-factory/meson.build || die
+	sed -i -e 's/^objcopy =.*/objcopy = disabler()/g' gtk/meson.build demos/gtk-demo/meson.build demos/widget-factory/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		# GDK backends
+		$(meson_use X x11-backend)
+		$(meson_use wayland wayland-backend)
+		$(meson_use broadway broadway-backend)
+		-Dwin32-backend=true
+		$(meson_use aqua macos-backend)
+
+		# Media backends
+		$(meson_feature ffmpeg media-ffmpeg)
+		$(meson_feature gstreamer media-gstreamer)
+
+		# Print backends
+		$(meson_feature cups print-cups)
+
+		# Optional dependencies
+		$(meson_feature vulkan)
+		-Dcloudproviders=disabled  # cloudprovider is not packaged in Gentoo yet
+		$(meson_feature sysprof)
+		-Dtracker=disabled  # tracker3 is not packaged in Gentoo yet
+		$(meson_feature colord)
+		# Expected to fail with GCC < 11
+		# See https://gcc.gnu.org/bugzilla/show_bug.cgi?id=71993
+		$(meson_feature cpu_flags_x86_f16c f16c)
+
+		# Documentation and introspection
+		-Dgtk_doc=false # we ship pregenerated API docs from tarball
+		-Dman-pages=true
+		$(meson_feature introspection)
+
+		# Demos and binaries
+		$(meson_use examples build-examples)
+		$(meson_use examples demos)
+		$(meson_use test build-tests)
+		-Dinstall-tests=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	"${BROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/gtk" || die
+
+	if use X; then
+		einfo "Running tests under X"
+		GSETTINGS_SCHEMA_DIR="${S}/gtk" virtx meson_src_test --setup=x11
+	fi
+
+	if use wayland; then
+		einfo "Running tests under Weston"
+
+		export XDG_RUNTIME_DIR="$(mktemp -p $(pwd) -d xdg-runtime-XXXXXX)"
+
+		weston --backend=headless-backend.so --socket=wayland-5 --idle-time=0 &
+		compositor=$!
+		export WAYLAND_DISPLAY=wayland-5
+
+		GSETTINGS_SCHEMA_DIR="${S}/gtk" meson_src_test --setup=wayland
+
+		exit_code=$?
+		kill ${compositor}
+	fi
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /usr/share/gtk-doc/html
+	# This will install API docs specific to X11 and wayland regardless of USE flags, but this is intentional
+	doins -r "${S}"/docs/reference/{gtk/gtk4,gsk/gsk4,gdk/gdk4{,-wayland,-x11}}
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	if ! has_version "app-text/evince"; then
+		elog "Please install app-text/evince for print preview functionality."
+		elog "Alternatively, check \"gtk-print-preview-command\" documentation and"
+		elog "add it to your settings.ini file."
+	fi
+
+	if use examples ; then
+		optfeature "syntax highlighting in gtk4-demo" app-text/highlight
+	fi
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
--- a/media-libs/mesa/mesa-22.1.2.ebuild
+++ b/media-libs/mesa/mesa-22.1.2.ebuild
@ -0,0 +1,460 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit llvm meson-multilib python-any-r1 linux-info
+
+MY_P="${P/_/-}"
+
+DESCRIPTION="OpenGL-like graphic library for Linux"
+HOMEPAGE="https://www.mesa3d.org/ https://mesa.freedesktop.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/mesa.git"
+	inherit git-r3
+else
+	SRC_URI="https://archive.mesa3d.org/${MY_P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+RESTRICT="!test? ( test )"
+
+RADEON_CARDS="r300 r600 radeon radeonsi"
+VIDEO_CARDS="${RADEON_CARDS} freedreno intel lima nouveau panfrost v3d vc4 virgl vivante vmware"
+for card in ${VIDEO_CARDS}; do
+	IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+
+IUSE="${IUSE_VIDEO_CARDS}
+	cpu_flags_x86_sse2 d3d9 debug gles1 +gles2 +llvm
+	lm-sensors opencl osmesa selinux test unwind vaapi valgrind vdpau vulkan
+	vulkan-overlay wayland +X xa xvmc zink +zstd"
+
+REQUIRED_USE="
+	d3d9?   ( || ( video_cards_intel video_cards_r300 video_cards_r600 video_cards_radeonsi video_cards_nouveau video_cards_vmware ) )
+	vulkan? ( video_cards_radeonsi? ( llvm ) )
+	vulkan-overlay? ( vulkan )
+	video_cards_radeon? ( x86? ( llvm ) amd64? ( llvm ) )
+	video_cards_r300?   ( x86? ( llvm ) amd64? ( llvm ) )
+	video_cards_radeonsi?   ( llvm )
+	xa? ( X )
+	xvmc? ( X )
+	zink? ( vulkan )
+"
+
+LIBDRM_DEPSTRING=">=x11-libs/libdrm-2.4.110"
+RDEPEND="
+	>=dev-libs/expat-2.1.0-r3:=[${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8[${MULTILIB_USEDEP}]
+	unwind? ( sys-libs/libunwind[${MULTILIB_USEDEP}] )
+	llvm? (
+		video_cards_radeonsi? (
+			virtual/libelf:0=[${MULTILIB_USEDEP}]
+		)
+		video_cards_r600? (
+			virtual/libelf:0=[${MULTILIB_USEDEP}]
+		)
+		video_cards_radeon? (
+			virtual/libelf:0=[${MULTILIB_USEDEP}]
+		)
+	)
+	lm-sensors? ( sys-apps/lm-sensors:=[${MULTILIB_USEDEP}] )
+	opencl? (
+				>=virtual/opencl-3[${MULTILIB_USEDEP}]
+				dev-libs/libclc
+				virtual/libelf:0=[${MULTILIB_USEDEP}]
+			)
+	vaapi? (
+		>=x11-libs/libva-1.7.3:=[${MULTILIB_USEDEP}]
+	)
+	vdpau? ( >=x11-libs/libvdpau-1.1:=[${MULTILIB_USEDEP}] )
+	xvmc? ( >=x11-libs/libXvMC-1.0.8:=[${MULTILIB_USEDEP}] )
+	selinux? ( sys-libs/libselinux[${MULTILIB_USEDEP}] )
+	wayland? (
+		>=dev-libs/wayland-1.18.0:=[${MULTILIB_USEDEP}]
+	)
+	${LIBDRM_DEPSTRING}[video_cards_freedreno?,video_cards_intel?,video_cards_nouveau?,video_cards_vc4?,video_cards_vivante?,video_cards_vmware?,${MULTILIB_USEDEP}]
+	vulkan-overlay? ( dev-util/glslang:0=[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2:=[${MULTILIB_USEDEP}]
+		>=x11-libs/libxshmfence-1.1:=[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2:=[${MULTILIB_USEDEP}]
+		>=x11-libs/libXxf86vm-1.1.3:=[${MULTILIB_USEDEP}]
+		>=x11-libs/libxcb-1.13:=[${MULTILIB_USEDEP}]
+		x11-libs/libXfixes:=[${MULTILIB_USEDEP}]
+	)
+	zink? ( media-libs/vulkan-loader:=[${MULTILIB_USEDEP}] )
+	zstd? ( app-arch/zstd:=[${MULTILIB_USEDEP}] )
+"
+for card in ${RADEON_CARDS}; do
+	RDEPEND="${RDEPEND}
+		video_cards_${card}? ( ${LIBDRM_DEPSTRING}[video_cards_radeon] )
+	"
+done
+RDEPEND="${RDEPEND}
+	video_cards_radeonsi? ( ${LIBDRM_DEPSTRING}[video_cards_amdgpu] )
+"
+
+# Please keep the LLVM dependency block separate. Since LLVM is slotted,
+# we need to *really* make sure we're not pulling one than more slot
+# simultaneously.
+#
+# How to use it:
+# 1. List all the working slots (with min versions) in ||, newest first.
+# 2. Update the := to specify *max* version, e.g. < 10.
+# 3. Specify LLVM_MAX_SLOT, e.g. 9.
+LLVM_MAX_SLOT="14"
+LLVM_DEPSTR="
+	|| (
+		sys-devel/llvm:14[${MULTILIB_USEDEP}]
+		sys-devel/llvm:13[${MULTILIB_USEDEP}]
+		sys-devel/llvm:12[${MULTILIB_USEDEP}]
+	)
+	<sys-devel/llvm-$((LLVM_MAX_SLOT + 1)):=[${MULTILIB_USEDEP}]
+"
+LLVM_DEPSTR_AMDGPU=${LLVM_DEPSTR//]/,llvm_targets_AMDGPU(-)]}
+CLANG_DEPSTR=${LLVM_DEPSTR//llvm/clang}
+CLANG_DEPSTR_AMDGPU=${CLANG_DEPSTR//]/,llvm_targets_AMDGPU(-)]}
+RDEPEND="${RDEPEND}
+	llvm? (
+		opencl? (
+			video_cards_r600? (
+				${CLANG_DEPSTR_AMDGPU}
+			)
+			!video_cards_r600? (
+				video_cards_radeonsi? (
+					${CLANG_DEPSTR_AMDGPU}
+				)
+			)
+			!video_cards_r600? (
+				!video_cards_radeonsi? (
+					video_cards_radeon? (
+						${CLANG_DEPSTR_AMDGPU}
+					)
+				)
+			)
+			!video_cards_r600? (
+				!video_cards_radeon? (
+					!video_cards_radeonsi? (
+						${CLANG_DEPSTR}
+					)
+				)
+			)
+		)
+		!opencl? (
+			video_cards_r600? (
+				${LLVM_DEPSTR_AMDGPU}
+			)
+			!video_cards_r600? (
+				video_cards_radeonsi? (
+					${LLVM_DEPSTR_AMDGPU}
+				)
+			)
+			!video_cards_r600? (
+				!video_cards_radeonsi? (
+					video_cards_radeon? (
+						${LLVM_DEPSTR_AMDGPU}
+					)
+				)
+			)
+			!video_cards_r600? (
+				!video_cards_radeon? (
+					!video_cards_radeonsi? (
+						${LLVM_DEPSTR}
+					)
+				)
+			)
+		)
+	)
+"
+unset {LLVM,CLANG}_DEPSTR{,_AMDGPU}
+
+DEPEND="${RDEPEND}
+	valgrind? ( dev-util/valgrind )
+	wayland? ( >=dev-libs/wayland-protocols-1.24 )
+	X? (
+		x11-libs/libXrandr[${MULTILIB_USEDEP}]
+		x11-base/xorg-proto
+	)
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	opencl? (
+		>=sys-devel/gcc-4.6
+	)
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+	$(python_gen_any_dep ">=dev-python/mako-0.8.0[\${PYTHON_USEDEP}]")
+	wayland? ( dev-util/wayland-scanner )
+"
+
+S="${WORKDIR}/${MY_P}"
+EGIT_CHECKOUT_DIR=${S}
+
+QA_WX_LOAD="
+x86? (
+	usr/lib*/libglapi.so.0.0.0
+	usr/lib*/libGLESv1_CM.so.1.1.0
+	usr/lib*/libGLESv2.so.2.0.0
+	usr/lib*/libGL.so.1.2.0
+	usr/lib*/libOSMesa.so.8.0.0
+	usr/lib/libGLX_mesa.so.0.0.0
+)"
+
+llvm_check_deps() {
+	local flags=${MULTILIB_USEDEP}
+	if use video_cards_r600 || use video_cards_radeon || use video_cards_radeonsi
+	then
+		flags+=",llvm_targets_AMDGPU(-)"
+	fi
+
+	if use opencl; then
+		has_version "sys-devel/clang:${LLVM_SLOT}[${flags}]" || return 1
+	fi
+	has_version "sys-devel/llvm:${LLVM_SLOT}[${flags}]"
+}
+
+pkg_pretend() {
+	if use vulkan; then
+		if ! use video_cards_freedreno &&
+		   ! use video_cards_intel &&
+		   ! use video_cards_radeonsi &&
+		   ! use video_cards_v3d; then
+			ewarn "Ignoring USE=vulkan     since VIDEO_CARDS does not contain freedreno, intel, radeonsi, or v3d"
+		fi
+	fi
+
+	if use opencl; then
+		if ! use video_cards_r600 &&
+		   ! use video_cards_radeonsi; then
+			ewarn "Ignoring USE=opencl     since VIDEO_CARDS does not contain r600 or radeonsi"
+		fi
+	fi
+
+	if use vaapi; then
+		if ! use video_cards_r600 &&
+		   ! use video_cards_radeonsi &&
+		   ! use video_cards_nouveau; then
+			ewarn "Ignoring USE=vaapi      since VIDEO_CARDS does not contain r600, radeonsi, or nouveau"
+		fi
+	fi
+
+	if use vdpau; then
+		if ! use video_cards_r300 &&
+		   ! use video_cards_r600 &&
+		   ! use video_cards_radeonsi &&
+		   ! use video_cards_nouveau; then
+			ewarn "Ignoring USE=vdpau      since VIDEO_CARDS does not contain r300, r600, radeonsi, or nouveau"
+		fi
+	fi
+
+	if use xa; then
+		if ! use video_cards_freedreno &&
+		   ! use video_cards_nouveau &&
+		   ! use video_cards_vmware; then
+			ewarn "Ignoring USE=xa         since VIDEO_CARDS does not contain freedreno, nouveau, or vmware"
+		fi
+	fi
+
+	if use xvmc; then
+		if ! use video_cards_r600 &&
+		   ! use video_cards_nouveau; then
+			ewarn "Ignoring USE=xvmc       since VIDEO_CARDS does not contain r600 or nouveau"
+		fi
+	fi
+
+	if ! use llvm; then
+		use opencl     && ewarn "Ignoring USE=opencl     since USE does not contain llvm"
+	fi
+
+	if use osmesa && ! use llvm; then
+		ewarn "OSMesa will be slow without enabling USE=llvm"
+	fi
+}
+
+python_check_deps() {
+	python_has_version -b ">=dev-python/mako-0.8.0[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	# warning message for bug 459306
+	if use llvm && has_version sys-devel/llvm[!debug=]; then
+		ewarn "Mismatch between debug USE flags in media-libs/mesa and sys-devel/llvm"
+		ewarn "detected! This can cause problems. For details, see bug 459306."
+	fi
+
+	if use video_cards_intel ||
+	   use video_cards_radeonsi; then
+		if kernel_is -ge 5 11 3; then
+			CONFIG_CHECK="~KCMP"
+		elif kernel_is -ge 5 11; then
+			CONFIG_CHECK="~CHECKPOINT_RESTORE"
+		elif kernel_is -ge 5 10 20; then
+			CONFIG_CHECK="~KCMP"
+		else
+			CONFIG_CHECK="~CHECKPOINT_RESTORE"
+		fi
+		linux-info_pkg_setup
+	fi
+
+	if use llvm; then
+		llvm_pkg_setup
+	fi
+	python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local emesonargs=()
+
+	local platforms
+	use X && platforms+="x11"
+	use wayland && platforms+=",wayland"
+	emesonargs+=(-Dplatforms=${platforms#,})
+
+	if use video_cards_intel ||
+	   use video_cards_r300 ||
+	   use video_cards_r600 ||
+	   use video_cards_radeonsi ||
+	   use video_cards_nouveau ||
+	   use video_cards_vmware; then
+		emesonargs+=($(meson_use d3d9 gallium-nine))
+	else
+		emesonargs+=(-Dgallium-nine=false)
+	fi
+
+	if use video_cards_r600 ||
+	   use video_cards_radeonsi ||
+	   use video_cards_nouveau; then
+		emesonargs+=($(meson_feature vaapi gallium-va))
+		use vaapi && emesonargs+=( -Dva-libs-path="${EPREFIX}"/usr/$(get_libdir)/va/drivers )
+	else
+		emesonargs+=(-Dgallium-va=disabled)
+	fi
+
+	if use video_cards_r300 ||
+	   use video_cards_r600 ||
+	   use video_cards_radeonsi ||
+	   use video_cards_nouveau; then
+		emesonargs+=($(meson_feature vdpau gallium-vdpau))
+	else
+		emesonargs+=(-Dgallium-vdpau=disabled)
+	fi
+
+	if use video_cards_freedreno ||
+	   use video_cards_nouveau ||
+	   use video_cards_vmware; then
+		emesonargs+=($(meson_feature xa gallium-xa))
+	else
+		emesonargs+=(-Dgallium-xa=disabled)
+	fi
+
+	if use video_cards_r600 ||
+	   use video_cards_nouveau; then
+		emesonargs+=($(meson_feature xvmc gallium-xvmc))
+	else
+		emesonargs+=(-Dgallium-xvmc=disabled)
+	fi
+
+	if use video_cards_freedreno ||
+	   use video_cards_lima ||
+	   use video_cards_panfrost ||
+	   use video_cards_v3d ||
+	   use video_cards_vc4 ||
+	   use video_cards_vivante; then
+		gallium_enable -- kmsro
+	fi
+
+	gallium_enable -- swrast
+	gallium_enable video_cards_freedreno freedreno
+	gallium_enable video_cards_intel crocus i915 iris
+	gallium_enable video_cards_lima lima
+	gallium_enable video_cards_nouveau nouveau
+	gallium_enable video_cards_panfrost panfrost
+	gallium_enable video_cards_v3d v3d
+	gallium_enable video_cards_vc4 vc4
+	gallium_enable video_cards_virgl virgl
+	gallium_enable video_cards_vivante etnaviv
+	gallium_enable video_cards_vmware svga
+	gallium_enable zink zink
+
+	gallium_enable video_cards_r300 r300
+	gallium_enable video_cards_r600 r600
+	gallium_enable video_cards_radeonsi radeonsi
+	if ! use video_cards_r300 && \
+		! use video_cards_r600; then
+		gallium_enable video_cards_radeon r300 r600
+	fi
+
+	# opencl stuff
+	emesonargs+=(
+		-Dgallium-opencl="$(usex opencl icd disabled)"
+	)
+
+	if use vulkan; then
+		vulkan_enable video_cards_freedreno freedreno
+		vulkan_enable video_cards_intel intel
+		vulkan_enable video_cards_radeonsi amd
+		vulkan_enable video_cards_v3d broadcom
+	fi
+
+	driver_list() {
+		local drivers="$(sort -u <<< "${1// /$'\n'}")"
+		echo "${drivers//$'\n'/,}"
+	}
+
+	local vulkan_layers
+	use vulkan && vulkan_layers+="device-select"
+	use vulkan-overlay && vulkan_layers+=",overlay"
+	emesonargs+=(-Dvulkan-layers=${vulkan_layers#,})
+
+	emesonargs+=(
+		$(meson_use test build-tests)
+		-Dglx=$(usex X dri disabled)
+		-Dshared-glapi=enabled
+		-Ddri3=enabled
+		-Degl=enabled
+		-Dgbm=enabled
+		-Dglvnd=false
+		$(meson_feature gles1)
+		$(meson_feature gles2)
+		$(meson_feature llvm)
+		$(meson_feature lm-sensors lmsensors)
+		$(meson_use osmesa)
+		$(meson_use selinux)
+		$(meson_feature unwind libunwind)
+		$(meson_feature zstd)
+		$(meson_use cpu_flags_x86_sse2 sse2)
+		-Dvalgrind=$(usex valgrind auto disabled)
+		-Dgallium-drivers=$(driver_list "${GALLIUM_DRIVERS[*]}")
+		-Dvulkan-drivers=$(driver_list "${VULKAN_DRIVERS[*]}")
+		--buildtype $(usex debug debug plain)
+		-Db_ndebug=$(usex debug false true)
+	)
+	meson_src_configure
+}
+
+multilib_src_test() {
+	meson_src_test -t 100
+}
+
+# $1 - VIDEO_CARDS flag (check skipped for "--")
+# other args - names of DRI drivers to enable
+gallium_enable() {
+	if [[ $1 == -- ]] || use $1; then
+		shift
+		GALLIUM_DRIVERS+=("$@")
+	fi
+}
+
+vulkan_enable() {
+	if [[ $1 == -- ]] || use $1; then
+		shift
+		VULKAN_DRIVERS+=("$@")
+	fi
+}
--- a/sys-libs/kbdus/files/meson.build
+++ b/sys-libs/kbdus/files/meson.build
@ -0,0 +1,12 @@
+project('org.reactos.kbdus', 'c')
+
+sources = [
+    'dll/keyboard/kbdus/kbdus.c'
+]
+
+library('KBDUS',
+    sources,
+    install: true,
+    install_dir: [true],
+    include_directories: ['sdk/include'],
+)
--- a/sys-libs/kbdus/kbdus-0.0.1.ebuild
+++ b/sys-libs/kbdus/kbdus-0.0.1.ebuild
@ -0,0 +1,35 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="KBDUS.DLL"
+HOMEPAGE="https://github.com/reactos/reactos"
+SRC_URI="https://github.com/reactos/reactos/archive/master.tar.gz -> reactos-master.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND=""
+RDEPEND="${DEPEND}"
+BDEPEND="
+>=dev-util/meson-0.60.3
+"
+
+inherit meson
+
+S="${WORKDIR}/reactos-master"
+
+src_configure() {
+	cp ${FILESDIR}/meson.build .
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+}
+
+src_install() {
+	meson_src_install
+}
--- a/sys-libs/owlpath/owlpath-0.0.1.ebuild
+++ b/sys-libs/owlpath/owlpath-0.0.1.ebuild
@ -0,0 +1,33 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="A path tiny clone for vala."
+HOMEPAGE="https://gitea.sergiotarxz.freemyip.com/sergiotarxz/OwlPath"
+SRC_URI="https://gitea.sergiotarxz.freemyip.com/sergiotarxz/OwlPath/archive/main.tar.gz -> owlpath-main.tar.gz"
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND=">=dev-libs/glib-2.72.1
+"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+inherit meson
+
+
+S="${WORKDIR}/${PN}"
+
+src_configure() {
+	VALAC=/usr/bin/valac-0.56 meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+}
+
+src_install() {
+	meson_src_install
+}