6086f42bfb
Support for the STMicroelectronics B-U585I-IOT02A development board. This is a proof-of-concept port that demonstrates running NuttX as the Non-Secure TrustZone domain companion to TrustedFirmware-M. Signed-off-by: Michael Jung <mijung@gmx.net>
115 lines
3.4 KiB
Plaintext
115 lines
3.4 KiB
Plaintext
/****************************************************************************
|
|
* boards/arm/stm32u5/b-u585i-iot02a/scripts/tfm-ns.ld
|
|
*
|
|
* Licensed to the Apache Software Foundation (ASF) under one or more
|
|
* contributor license agreements. See the NOTICE file distributed with
|
|
* this work for additional information regarding copyright ownership. The
|
|
* ASF licenses this file to you under the Apache License, Version 2.0 (the
|
|
* "License"); you may not use this file except in compliance with the
|
|
* License. You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
|
|
* WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
|
|
* License for the specific language governing permissions and limitations
|
|
* under the License.
|
|
*
|
|
****************************************************************************/
|
|
|
|
/* This linker script supports running NuttX in the 'Non-Secure' (ns) domain
|
|
* in conjunction with TrustedFirmware-M (tfm).
|
|
*
|
|
* NuttX will run as the 'Non secure application' in the 'Non-Secure image
|
|
* primary primary slot Area 1' in internal flash. Compare [UM2851],
|
|
* Figure 7. Furthermore, see Figure 18 for the SRAM1 area used for 'Non-
|
|
* Secure application volatile data'
|
|
*
|
|
* While the 'Non-Secure Image primary slot Area 1' is actually 640KiB large
|
|
* in the referenced setup, the image will be enriched with a header of 0x400
|
|
* bytes and a trailer of 0x2000 bytes. Thus the 'flash' statement in the
|
|
* MEMORY definition below.
|
|
*
|
|
* References
|
|
* [UM2851] STMicroelectronics. UM2851: Getting started with STM32CubeU5 TFM
|
|
* application, Rev 1, June 2021
|
|
*/
|
|
|
|
MEMORY
|
|
{
|
|
flash (rx) : ORIGIN = 0x08052400, LENGTH = 0x9DC00
|
|
sram (rwx) : ORIGIN = 0x20000000, LENGTH = 192K
|
|
}
|
|
|
|
OUTPUT_ARCH(arm)
|
|
ENTRY(_stext)
|
|
SECTIONS
|
|
{
|
|
.text : {
|
|
_stext = ABSOLUTE(.);
|
|
*(.vectors)
|
|
*(.text .text.*)
|
|
*(.fixup)
|
|
*(.gnu.warning)
|
|
*(.rodata .rodata.*)
|
|
*(.gnu.linkonce.t.*)
|
|
*(.glue_7)
|
|
*(.glue_7t)
|
|
*(.got)
|
|
*(.gcc_except_table)
|
|
*(.gnu.linkonce.r.*)
|
|
_etext = ABSOLUTE(.);
|
|
} > flash
|
|
|
|
.init_section : {
|
|
_sinit = ABSOLUTE(.);
|
|
*(.init_array .init_array.*)
|
|
_einit = ABSOLUTE(.);
|
|
} > flash
|
|
|
|
.ARM.extab : {
|
|
*(.ARM.extab*)
|
|
} > flash
|
|
|
|
__exidx_start = ABSOLUTE(.);
|
|
.ARM.exidx : {
|
|
*(.ARM.exidx*)
|
|
} > flash
|
|
__exidx_end = ABSOLUTE(.);
|
|
|
|
_eronly = ABSOLUTE(.);
|
|
|
|
.data : {
|
|
_sdata = ABSOLUTE(.);
|
|
*(.data .data.*)
|
|
*(.gnu.linkonce.d.*)
|
|
CONSTRUCTORS
|
|
. = ALIGN(4);
|
|
_edata = ABSOLUTE(.);
|
|
} > sram AT > flash
|
|
|
|
.bss : {
|
|
_sbss = ABSOLUTE(.);
|
|
*(.bss .bss.*)
|
|
*(.gnu.linkonce.b.*)
|
|
*(COMMON)
|
|
. = ALIGN(4);
|
|
_ebss = ABSOLUTE(.);
|
|
} > sram
|
|
|
|
/* Stabs debugging sections. */
|
|
.stab 0 : { *(.stab) }
|
|
.stabstr 0 : { *(.stabstr) }
|
|
.stab.excl 0 : { *(.stab.excl) }
|
|
.stab.exclstr 0 : { *(.stab.exclstr) }
|
|
.stab.index 0 : { *(.stab.index) }
|
|
.stab.indexstr 0 : { *(.stab.indexstr) }
|
|
.comment 0 : { *(.comment) }
|
|
.debug_abbrev 0 : { *(.debug_abbrev) }
|
|
.debug_info 0 : { *(.debug_info) }
|
|
.debug_line 0 : { *(.debug_line) }
|
|
.debug_pubnames 0 : { *(.debug_pubnames) }
|
|
.debug_aranges 0 : { *(.debug_aranges) }
|
|
}
|