008803865f
This PR adds support for Milk-V Duo S 64-bit RISC-V SBC, based on SOPHGO SG2000 SoC (T-Head C906 Core). Most of the code is derived from NuttX for Ox64 BL808. The source files are explained in the articles here: https://github.com/lupyuen/nuttx-sg2000 Modified Files: `boards/Kconfig`: Added Milk-V Duo S board `arch/risc-v/src/sg2000/sg2000_timerisr.c`: Fixed MTIMER_FREQ for sleep() to work correctly New Files in boards/risc-v/sg2000/milkv_duos: `src/sg2000_appinit.c`: Startup Code `include/board.h`: Milk-V Duo S Definitions `include/board_memorymap.h`: Memory Map `src/etc/init.d/rc.sysinit`, `rcS`: Startup Script `src/.gitignore`: Ignore the tmp filesystem `scripts/ld.script`: Linker Script `scripts/Make.defs`: Milk-V Duo S Makefile `src/Makefile`: Milk-V Duo S Makefile `Kconfig`: Milk-V Duo S Config `configs/nsh/defconfig`: Build Config for `milkv_duos:nsh` Updated Documentation: `platforms/risc-v/sg2000/index.rst`: New page for SOPHGO SG2000 SoC `platforms/risc-v/sg2000/boards/milkv_duos/index.rst`: Building and booting NuttX for Milk-V Duo S
152 lines
3.7 KiB
Plaintext
152 lines
3.7 KiB
Plaintext
/****************************************************************************
|
|
* boards/risc-v/sg2000/milkv_duos/scripts/ld.script
|
|
*
|
|
* Licensed to the Apache Software Foundation (ASF) under one or more
|
|
* contributor license agreements. See the NOTICE file distributed with
|
|
* this work for additional information regarding copyright ownership. The
|
|
* ASF licenses this file to you under the Apache License, Version 2.0 (the
|
|
* "License"); you may not use this file except in compliance with the
|
|
* License. You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
|
|
* WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
|
|
* License for the specific language governing permissions and limitations
|
|
* under the License.
|
|
*
|
|
****************************************************************************/
|
|
|
|
MEMORY
|
|
{
|
|
kflash (rx) : ORIGIN = 0x80200000, LENGTH = 2048K /* w/ cache */
|
|
ksram (rwx) : ORIGIN = 0x80400000, LENGTH = 2048K /* w/ cache */
|
|
pgram (rwx) : ORIGIN = 0x80600000, LENGTH = 4096K /* w/ cache */
|
|
ramdisk (rwx) : ORIGIN = 0x80A00000, LENGTH = 16M /* w/ cache */
|
|
}
|
|
|
|
OUTPUT_ARCH("riscv")
|
|
|
|
/* Provide the kernel boundaries */
|
|
|
|
__kflash_start = ORIGIN(kflash);
|
|
__kflash_size = LENGTH(kflash);
|
|
__ksram_start = ORIGIN(ksram);
|
|
__ksram_size = LENGTH(ksram);
|
|
__ksram_end = ORIGIN(ksram) + LENGTH(ksram);
|
|
|
|
/* Page heap */
|
|
|
|
__pgheap_start = ORIGIN(pgram);
|
|
__pgheap_size = LENGTH(pgram) + LENGTH(ramdisk);
|
|
|
|
/* Application ramdisk */
|
|
|
|
__ramdisk_start = ORIGIN(ramdisk);
|
|
__ramdisk_size = LENGTH(ramdisk);
|
|
__ramdisk_end = ORIGIN(ramdisk) + LENGTH(ramdisk);
|
|
|
|
SECTIONS
|
|
{
|
|
. = 0x80200000;
|
|
|
|
.text :
|
|
{
|
|
_stext = . ;
|
|
*(.text)
|
|
*(.text.*)
|
|
*(.gnu.warning)
|
|
*(.stub)
|
|
*(.glue_7)
|
|
*(.glue_7t)
|
|
*(.jcr)
|
|
|
|
/* C++ support: The .init and .fini sections contain specific logic
|
|
* to manage static constructors and destructors.
|
|
*/
|
|
|
|
*(.gnu.linkonce.t.*)
|
|
*(.init) /* Old ABI */
|
|
*(.fini) /* Old ABI */
|
|
_etext = . ;
|
|
}
|
|
|
|
.rodata :
|
|
{
|
|
_srodata = . ;
|
|
*(.rodata)
|
|
*(.rodata1)
|
|
*(.rodata.*)
|
|
*(.gnu.linkonce.r*)
|
|
_erodata = . ;
|
|
}
|
|
|
|
.tdata : {
|
|
_stdata = ABSOLUTE(.);
|
|
*(.tdata .tdata.* .gnu.linkonce.td.*);
|
|
_etdata = ABSOLUTE(.);
|
|
}
|
|
|
|
.tbss : {
|
|
_stbss = ABSOLUTE(.);
|
|
*(.tbss .tbss.* .gnu.linkonce.tb.* .tcommon);
|
|
_etbss = ABSOLUTE(.);
|
|
}
|
|
|
|
_eronly = ABSOLUTE(.);
|
|
|
|
.data :
|
|
{
|
|
_sdata = . ;
|
|
*(.data)
|
|
*(.data1)
|
|
*(.data.*)
|
|
*(.gnu.linkonce.d*)
|
|
. = ALIGN(4);
|
|
_edata = . ;
|
|
}
|
|
|
|
.bss :
|
|
{
|
|
_sbss = . ;
|
|
*(.bss)
|
|
*(.bss.*)
|
|
*(.sbss)
|
|
*(.sbss.*)
|
|
*(.gnu.linkonce.b*)
|
|
*(COMMON)
|
|
. = ALIGN(32);
|
|
_ebss = . ;
|
|
} > ksram
|
|
|
|
/* Page tables here, align to 4K boundary */
|
|
|
|
.pgtables (NOLOAD) : ALIGN(0x1000) {
|
|
*(.pgtables)
|
|
. = ALIGN(4);
|
|
} > ksram
|
|
|
|
/* Stack top */
|
|
|
|
.stack_top : {
|
|
. = ALIGN(32);
|
|
_ebss = ABSOLUTE(.);
|
|
} > ksram
|
|
|
|
/* Stabs debugging sections. */
|
|
|
|
.stab 0 : { *(.stab) }
|
|
.stabstr 0 : { *(.stabstr) }
|
|
.stab.excl 0 : { *(.stab.excl) }
|
|
.stab.exclstr 0 : { *(.stab.exclstr) }
|
|
.stab.index 0 : { *(.stab.index) }
|
|
.stab.indexstr 0 : { *(.stab.indexstr) }
|
|
.comment 0 : { *(.comment) }
|
|
.debug_abbrev 0 : { *(.debug_abbrev) }
|
|
.debug_info 0 : { *(.debug_info) }
|
|
.debug_line 0 : { *(.debug_line) }
|
|
.debug_pubnames 0 : { *(.debug_pubnames) }
|
|
.debug_aranges 0 : { *(.debug_aranges) }
|
|
}
|