dd1365ef85
Additions: - In arch/risc-v/src/k230/ - k230_userspace.c add user space initialization - k230_userspace.h headers for user space initialization - In boards/risc-v/k230/canmv230/kernel/ - k230_userspace.c userspace_s const data definition - Makefile pass1 Makefile - In boards/risc-v/k230/canmv230/scripts/ - ld-protected.script linker script for protected build kernel - ld-userland.script linker script for protected build userspace - In boards/risc-v/k230/canmv230/configs - pnsh/defconfig defconfig for protected build Changes: - In arch/risc-v/src/k230/ - k230_start.c add protected build handling logic - Make.defs add protected build support - In boards/risc-v/k230/canmv230/scripts/ - Make.defs add protected build support - In Documentation/platforms/risc-v/k230/boards/canmv230/ - index.rst add protected build usage Signed-off-by: Yanfeng Liu <yfliu2008@qq.com>
113 lines
3.3 KiB
Plaintext
113 lines
3.3 KiB
Plaintext
/****************************************************************************
|
|
* boards/risc-v/k230/canmv230/scripts/ld-userland.script
|
|
*
|
|
* Licensed to the Apache Software Foundation (ASF) under one or more
|
|
* contributor license agreements. See the NOTICE file distributed with
|
|
* this work for additional information regarding copyright ownership. The
|
|
* ASF licenses this file to you under the Apache License, Version 2.0 (the
|
|
* "License"); you may not use this file except in compliance with the
|
|
* License. You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
|
|
* WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
|
|
* License for the specific language governing permissions and limitations
|
|
* under the License.
|
|
*
|
|
****************************************************************************/
|
|
|
|
/* NOTE: This shares memory layout with ld-protected.script */
|
|
|
|
MEMORY
|
|
{
|
|
kflash (rx) : ORIGIN = 0x8000000, LENGTH = 256K /* w/ cache */
|
|
uflash (rx) : ORIGIN = 0x8040000, LENGTH = 256K /* w/ cache */
|
|
|
|
ksram (rwx) : ORIGIN = 0x8200000, LENGTH = 1024K /* w/ cache */
|
|
usram (rwx) : ORIGIN = 0x8300000, LENGTH = 1024K /* w/ cache */
|
|
}
|
|
|
|
OUTPUT_ARCH("riscv")
|
|
|
|
SECTIONS
|
|
{
|
|
/* section info */
|
|
|
|
__ld_uflash_start = ORIGIN(uflash);
|
|
__ld_uflash_end = ORIGIN(uflash)+ LENGTH(uflash);
|
|
__ld_uflash_size = LENGTH(uflash);
|
|
|
|
__ld_usram_start = ORIGIN(usram);
|
|
__ld_usram_end = ORIGIN(usram)+ LENGTH(usram);
|
|
__ld_usram_size = LENGTH(usram);
|
|
|
|
.userspace : {
|
|
*(.userspace)
|
|
} > uflash
|
|
|
|
.text : {
|
|
_stext = ABSOLUTE(.);
|
|
*(.text .text.*)
|
|
*(.fixup)
|
|
*(.gnu.warning)
|
|
*(.rodata .rodata.* .srodata .srodata.*)
|
|
*(.gnu.linkonce.t.*)
|
|
*(.glue_7)
|
|
*(.glue_7t)
|
|
*(.got)
|
|
*(.gcc_except_table)
|
|
*(.gnu.linkonce.r.*)
|
|
_etext = ABSOLUTE(.);
|
|
} > uflash
|
|
|
|
.init_section : {
|
|
_sinit = ABSOLUTE(.);
|
|
KEEP(*(SORT_BY_INIT_PRIORITY(.init_array.*) SORT_BY_INIT_PRIORITY(.ctors.*)))
|
|
KEEP(*(.init_array .ctors))
|
|
_einit = ABSOLUTE(.);
|
|
} > uflash
|
|
|
|
__exidx_start = ABSOLUTE(.);
|
|
|
|
__exidx_end = ABSOLUTE(.);
|
|
|
|
_eronly = ABSOLUTE(.);
|
|
|
|
.data : {
|
|
_sdata = ABSOLUTE(.);
|
|
*(.data .data.*)
|
|
*(.sdata .sdata.* .sdata2.*)
|
|
*(.gnu.linkonce.d.*)
|
|
CONSTRUCTORS
|
|
. = ALIGN(4);
|
|
_edata = ABSOLUTE(.);
|
|
} > usram AT > uflash
|
|
|
|
.bss : {
|
|
_sbss = ABSOLUTE(.);
|
|
*(.bss .bss.*)
|
|
*(.sbss .sbss.*)
|
|
*(.gnu.linkonce.b.*)
|
|
*(COMMON)
|
|
. = ALIGN(4);
|
|
_ebss = ABSOLUTE(.);
|
|
} > usram
|
|
|
|
/* Stabs debugging sections. */
|
|
|
|
.stab 0 : { *(.stab) }
|
|
.stabstr 0 : { *(.stabstr) }
|
|
.stab.excl 0 : { *(.stab.excl) }
|
|
.stab.exclstr 0 : { *(.stab.exclstr) }
|
|
.stab.index 0 : { *(.stab.index) }
|
|
.stab.indexstr 0 : { *(.stab.indexstr) }
|
|
.comment 0 : { *(.comment) }
|
|
.debug_abbrev 0 : { *(.debug_abbrev) }
|
|
.debug_info 0 : { *(.debug_info) }
|
|
.debug_line 0 : { *(.debug_line) }
|
|
.debug_pubnames 0 : { *(.debug_pubnames) }
|
|
.debug_aranges 0 : { *(.debug_aranges) }
|
|
}
|