31b916c485
Mappings are done with vaddr=paddr. - I/O space mapped with two gigapages - Kernel space mapped to statically allocated page tables. 2MB of kernel memory is supported. - Page pool is mapped to the kernel space, to allow virtual memory access for the kernel e.g. to initialize the page memory when it is allocated.
127 lines
3.5 KiB
Plaintext
Executable File
127 lines
3.5 KiB
Plaintext
Executable File
/****************************************************************************
|
|
* boards/risc-v/mpfs/icicle/scripts/ld-kernel.script
|
|
*
|
|
* Licensed to the Apache Software Foundation (ASF) under one or more
|
|
* contributor license agreements. See the NOTICE file distributed with
|
|
* this work for additional information regarding copyright ownership. The
|
|
* ASF licenses this file to you under the Apache License, Version 2.0 (the
|
|
* "License"); you may not use this file except in compliance with the
|
|
* License. You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
|
|
* WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
|
|
* License for the specific language governing permissions and limitations
|
|
* under the License.
|
|
*
|
|
****************************************************************************/
|
|
|
|
/* Map memory so that the kernel itself has 256K executable and data memory,
|
|
* for a total of 0.5M, and the rest is given for the user tasks. A total of
|
|
* 4M is reserved which should be plenty
|
|
*/
|
|
|
|
MEMORY
|
|
{
|
|
kflash (rx) : ORIGIN = 0x80000000, LENGTH = 1024K /* w/ cache */
|
|
ksram (rwx) : ORIGIN = 0x80100000, LENGTH = 1024K /* w/ cache */
|
|
pgram (rwx) : ORIGIN = 0x80200000, LENGTH = 4096K /* w/ cache */
|
|
}
|
|
|
|
OUTPUT_ARCH("riscv")
|
|
|
|
/* Provide the kernel boundaries */
|
|
|
|
__kflash_start = ORIGIN(kflash);
|
|
__kflash_size = LENGTH(kflash);
|
|
__ksram_start = ORIGIN(ksram);
|
|
__ksram_size = LENGTH(ksram);
|
|
__ksram_end = ORIGIN(ksram) + LENGTH(ksram);
|
|
|
|
/* Page heap */
|
|
|
|
__pgheap_start = ORIGIN(pgram);
|
|
__pgheap_size = LENGTH(pgram);
|
|
|
|
ENTRY(_stext)
|
|
EXTERN(_vectors)
|
|
SECTIONS
|
|
{
|
|
.text : {
|
|
_stext = ABSOLUTE(.);
|
|
*(.vectors)
|
|
*(.text .text.*)
|
|
*(.fixup)
|
|
*(.gnu.warning)
|
|
*(.rodata .rodata.* .srodata .srodata.*)
|
|
*(.gnu.linkonce.t.*)
|
|
*(.glue_7)
|
|
*(.glue_7t)
|
|
*(.got)
|
|
*(.gcc_except_table)
|
|
*(.gnu.linkonce.r.*)
|
|
_etext = ABSOLUTE(.);
|
|
} > kflash
|
|
|
|
.init_section : ALIGN(4) {
|
|
_sinit = ABSOLUTE(.);
|
|
KEEP(*(.init_array .init_array.*))
|
|
_einit = ABSOLUTE(.);
|
|
} > kflash
|
|
|
|
_eronly = ABSOLUTE(.);
|
|
|
|
.data : ALIGN(4) {
|
|
_sdata = ABSOLUTE(.);
|
|
*(.data .data.*)
|
|
*(.sdata .sdata.* .sdata2.*)
|
|
*(.gnu.linkonce.d.*)
|
|
*(.gnu.linkonce.s.*)
|
|
CONSTRUCTORS
|
|
. = ALIGN(4);
|
|
_edata = ABSOLUTE(.);
|
|
} > ksram AT > kflash
|
|
|
|
PROVIDE(__global_pointer$ = _sdata + ((_edata - _sdata) / 2));
|
|
|
|
.bss : ALIGN(4) {
|
|
_sbss = ABSOLUTE(.);
|
|
*(.bss .bss.*)
|
|
*(.sbss .sbss.*)
|
|
*(.gnu.linkonce.b.*)
|
|
*(.gnu.linkonce.sb.*)
|
|
*(COMMON)
|
|
} > ksram
|
|
|
|
/* Page tables here, align to 4K boundary */
|
|
|
|
.pgtables : ALIGN(0x1000) {
|
|
*(.pgtables)
|
|
. = ALIGN(4);
|
|
} > ksram
|
|
|
|
/* Stack top */
|
|
|
|
.stack_top : {
|
|
. = ALIGN(32);
|
|
_ebss = ABSOLUTE(.);
|
|
} > ksram
|
|
|
|
/* Stabs debugging sections. */
|
|
|
|
.stab 0 : { *(.stab) }
|
|
.stabstr 0 : { *(.stabstr) }
|
|
.stab.excl 0 : { *(.stab.excl) }
|
|
.stab.exclstr 0 : { *(.stab.exclstr) }
|
|
.stab.index 0 : { *(.stab.index) }
|
|
.stab.indexstr 0 : { *(.stab.indexstr) }
|
|
.comment 0 : { *(.comment) }
|
|
.debug_abbrev 0 : { *(.debug_abbrev) }
|
|
.debug_info 0 : { *(.debug_info) }
|
|
.debug_line 0 : { *(.debug_line) }
|
|
.debug_pubnames 0 : { *(.debug_pubnames) }
|
|
.debug_aranges 0 : { *(.debug_aranges) }
|
|
}
|