7cb8e590a1
Changes: - Documentation/platforms/risc-v/k230 revised for both modes - arch/risc-v/include/k230/irq.h add S-mode IRQs - under arch/risc-v/src/k230 folder: - Make.defs drop use of k230_exception_m.S - hardware/k230_clint.h add S-mode defs, revised freq - k230_head.S unified flat/kernel mode support - k230_irq.c add S-mode support with debug dump - k230_mm_init.c revised for K230 S-mode - k230_start.c revised for flat/s-mode, - arch/risc-v/src/k230/k230_timerisr.c unified flat/s-mode support. - under boards/risc-v/k230/canmv230 folder: - configs/nsh/defconfig fix RAM size - include/board_memorymap.h cleanup for S-mode - src/.gitignore ignore romfs_boot.c - src/Makefile add romfs support Renames: - under boards/risc-v/k230/canmv230/src/ folder: - canmv_init.c from k230_appinit.c making room for more k230 devices Dropped: - under arch/risc-v/src/k230/ - k230_exception_m.S as hybrid mode not ready yet. New files in boards/riscv/k230/canmv230: - configs/knsh/defconfig S-mode config - scripts/ld-kernel.script S-mode linker script - src/romfs.h User space ROMFS defs needed in S-mode - src/romfs_stub.c Stub ROMFS image Signed-off-by: Yanfeng Liu <yfliu2008@qq.com>
144 lines
3.4 KiB
Plaintext
144 lines
3.4 KiB
Plaintext
/****************************************************************************
|
|
* boards/risc-v/k230/canmv230/scripts/ld-kernel.script
|
|
*
|
|
* Licensed to the Apache Software Foundation (ASF) under one or more
|
|
* contributor license agreements. See the NOTICE file distributed with
|
|
* this work for additional information regarding copyright ownership. The
|
|
* ASF licenses this file to you under the Apache License, Version 2.0 (the
|
|
* "License"); you may not use this file except in compliance with the
|
|
* License. You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
|
|
* WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
|
|
* License for the specific language governing permissions and limitations
|
|
* under the License.
|
|
*
|
|
****************************************************************************/
|
|
|
|
MEMORY
|
|
{
|
|
kflash (rx) : ORIGIN = 0x08200000, LENGTH = 2048K /* w/ cache */
|
|
ksram (rwx) : ORIGIN = 0x08400000, LENGTH = 2048K /* w/ cache */
|
|
pgram (rwx) : ORIGIN = 0x08600000, LENGTH = 10M /* w/ cache */
|
|
}
|
|
|
|
OUTPUT_ARCH("riscv")
|
|
|
|
/* Provide the kernel boundaries */
|
|
|
|
__kflash_start = ORIGIN(kflash);
|
|
__kflash_size = LENGTH(kflash);
|
|
__ksram_start = ORIGIN(ksram);
|
|
__ksram_size = LENGTH(ksram);
|
|
__ksram_end = ORIGIN(ksram) + LENGTH(ksram);
|
|
|
|
/* Page heap */
|
|
|
|
__pgheap_start = ORIGIN(pgram);
|
|
__pgheap_size = LENGTH(pgram);
|
|
|
|
SECTIONS
|
|
{
|
|
. = 0x8200000;
|
|
|
|
.text :
|
|
{
|
|
_stext = . ;
|
|
*(.text)
|
|
*(.text.*)
|
|
*(.gnu.warning)
|
|
*(.stub)
|
|
*(.glue_7)
|
|
*(.glue_7t)
|
|
*(.jcr)
|
|
|
|
/* C++ support: The .init and .fini sections contain specific logic
|
|
* to manage static constructors and destructors.
|
|
*/
|
|
|
|
*(.gnu.linkonce.t.*)
|
|
*(.init) /* Old ABI */
|
|
*(.fini) /* Old ABI */
|
|
_etext = . ;
|
|
}
|
|
|
|
.rodata :
|
|
{
|
|
_srodata = . ;
|
|
*(.rodata)
|
|
*(.rodata1)
|
|
*(.rodata.*)
|
|
*(.gnu.linkonce.r*)
|
|
_erodata = . ;
|
|
}
|
|
|
|
.tdata : {
|
|
_stdata = ABSOLUTE(.);
|
|
*(.tdata .tdata.* .gnu.linkonce.td.*);
|
|
_etdata = ABSOLUTE(.);
|
|
}
|
|
|
|
.tbss : {
|
|
_stbss = ABSOLUTE(.);
|
|
*(.tbss .tbss.* .gnu.linkonce.tb.* .tcommon);
|
|
_etbss = ABSOLUTE(.);
|
|
}
|
|
|
|
_eronly = ABSOLUTE(.);
|
|
|
|
.data :
|
|
{
|
|
_sdata = . ;
|
|
*(.data)
|
|
*(.data1)
|
|
*(.data.*)
|
|
*(.gnu.linkonce.d*)
|
|
. = ALIGN(4);
|
|
_edata = . ;
|
|
}
|
|
|
|
.bss :
|
|
{
|
|
_sbss = . ;
|
|
*(.bss)
|
|
*(.bss.*)
|
|
*(.sbss)
|
|
*(.sbss.*)
|
|
*(.gnu.linkonce.b*)
|
|
*(COMMON)
|
|
_ebss = . ;
|
|
} > ksram
|
|
|
|
/* Page tables here, align to 4K boundary */
|
|
|
|
.pgtables (NOLOAD) : ALIGN(0x1000) {
|
|
*(.pgtables)
|
|
. = ALIGN(4);
|
|
} > ksram
|
|
|
|
/* Stack top */
|
|
|
|
.stack_top : {
|
|
. = ALIGN(32);
|
|
_ebss = ABSOLUTE(.);
|
|
} > ksram
|
|
|
|
/* Stabs debugging sections. */
|
|
|
|
.stab 0 : { *(.stab) }
|
|
.stabstr 0 : { *(.stabstr) }
|
|
.stab.excl 0 : { *(.stab.excl) }
|
|
.stab.exclstr 0 : { *(.stab.exclstr) }
|
|
.stab.index 0 : { *(.stab.index) }
|
|
.stab.indexstr 0 : { *(.stab.indexstr) }
|
|
.comment 0 : { *(.comment) }
|
|
.debug_abbrev 0 : { *(.debug_abbrev) }
|
|
.debug_info 0 : { *(.debug_info) }
|
|
.debug_line 0 : { *(.debug_line) }
|
|
.debug_pubnames 0 : { *(.debug_pubnames) }
|
|
.debug_aranges 0 : { *(.debug_aranges) }
|
|
}
|