valgrind clang aarch64 patch

packages/valgrind/aarch64-setjmp.S

@@ -0,0 +1,128 @@
+/*
+ * Copyright (C) 2013 The Android Open Source Project
+ * All rights reserved.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ *  * Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ *  * Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in
+ *    the documentation and/or other materials provided with the
+ *    distribution.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+ * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+ * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+ * FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+ * COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+ * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+ * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
+ * OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
+ * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
+ * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
+ * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+#ifdef __aarch64__
+
+// Copied and simplified macros from bionic_asm.h.
+
+#define ENTRY(f) \
+    .text; \
+    .globl f; \
+    .type f, @function; \
+    f: \
+    .cfi_startproc \
+
+#define END(f) \
+    .cfi_endproc; \
+    .size f, .-f; \
+
+// According to AARCH64 PCS document we need to save the following
+// registers:
+//
+// Core     x19 - x30, sp (see section 5.1.1)
+// VFP      d8 - d15 (see section 5.1.2)
+//
+// NOTE: All the registers saved here will have 64 bit values.
+//       AAPCS mandates that the higher part of q registers do not need to
+//       be saved by the callee.
+//
+// The internal structure of a jmp_buf is totally private.
+// Current layout (changes from release to release):
+//
+// word   name            description
+// 0      sigflag/cookie  setjmp cookie in top 31 bits, signal mask flag in low bit
+// 1      sigmask         signal mask (not used with _setjmp / _longjmp)
+// 2      core_base       base of core registers (x19-x30, sp)
+// 15     float_base      base of float registers (d8-d15)
+// 23     checksum        checksum of core registers
+// 24     reserved        reserved entries (room to grow)
+// 32
+
+// 'sigmask' and 'checksum' are not used in this simplified version for valgrind.
+
+#define _JB_SIGFLAG     0
+#define _JB_SIGMASK     (_JB_SIGFLAG + 1)
+#define _JB_X30_SP      (_JB_SIGMASK + 1)
+#define _JB_X28_X29     (_JB_X30_SP  + 2)
+#define _JB_X26_X27     (_JB_X28_X29 + 2)
+#define _JB_X24_X25     (_JB_X26_X27 + 2)
+#define _JB_X22_X23     (_JB_X24_X25 + 2)
+#define _JB_X20_X21     (_JB_X22_X23 + 2)
+#define _JB_X19         (_JB_X20_X21 + 2)
+#define _JB_D14_D15     (_JB_X19 + 1)
+#define _JB_D12_D13     (_JB_D14_D15 + 2)
+#define _JB_D10_D11     (_JB_D12_D13 + 2)
+#define _JB_D8_D9       (_JB_D10_D11 + 2)
+
+// int setjmp(jmp_buf env);
+ENTRY(setjmp)
+  // Save core registers.
+  mov x10, sp
+  stp x30, x10, [x0, #(_JB_X30_SP  * 8)]
+  stp x28, x29, [x0, #(_JB_X28_X29 * 8)]
+  stp x26, x27, [x0, #(_JB_X26_X27 * 8)]
+  stp x24, x25, [x0, #(_JB_X24_X25 * 8)]
+  stp x22, x23, [x0, #(_JB_X22_X23 * 8)]
+  stp x20, x21, [x0, #(_JB_X20_X21 * 8)]
+  str x19,      [x0, #(_JB_X19     * 8)]
+
+  // Save floating point registers.
+  stp d14, d15, [x0, #(_JB_D14_D15 * 8)]
+  stp d12, d13, [x0, #(_JB_D12_D13 * 8)]
+  stp d10, d11, [x0, #(_JB_D10_D11 * 8)]
+  stp d8,  d9,  [x0, #(_JB_D8_D9   * 8)]
+
+  mov w0, #0
+  ret
+END(setjmp)
+
+// void longjmp(jmp_buf env, int value);
+ENTRY(longjmp)
+  // Restore core registers.
+  ldp x30, x10, [x0, #(_JB_X30_SP  * 8)]
+  ldp x28, x29, [x0, #(_JB_X28_X29 * 8)]
+  ldp x26, x27, [x0, #(_JB_X26_X27 * 8)]
+  ldp x24, x25, [x0, #(_JB_X24_X25 * 8)]
+  ldp x22, x23, [x0, #(_JB_X22_X23 * 8)]
+  ldp x20, x21, [x0, #(_JB_X20_X21 * 8)]
+  ldr x19,      [x0, #(_JB_X19     * 8)]
+  mov sp, x10
+
+  // Restore floating point registers.
+  ldp d14, d15, [x0, #(_JB_D14_D15 * 8)]
+  ldp d12, d13, [x0, #(_JB_D12_D13 * 8)]
+  ldp d10, d11, [x0, #(_JB_D10_D11 * 8)]
+  ldp d8,  d9,  [x0, #(_JB_D8_D9   * 8)]
+
+  // Set return value.
+  cmp w1, wzr
+  csinc w0, w1, wzr, ne
+  ret
+END(longjmp)
+
+#endif  // __aarch64__

packages/valgrind/build.sh

@@ -10,9 +10,13 @@ TERMUX_PKG_EXTRA_CONFIGURE_ARGS="--with-tmpdir=$TERMUX_PREFIX/tmp"
 # - Does not build on aarch64 using clang, fails with
 #   "`__builtin_longjmp is not supported for the current target"
 #   https://bugs.kde.org/show_bug.cgi?id=369723
-TERMUX_PKG_BLACKLISTED_ARCHES="aarch64, x86_64"
+TERMUX_PKG_BLACKLISTED_ARCHES="x86_64"
 
 termux_step_pre_configure() {
+	if [ "$TERMUX_ARCH" == "aarch64" ]; then
+		cp $TERMUX_PKG_BUILDER_DIR/aarch64-setjmp.S $TERMUX_PKG_SRCDIR
+		autoreconf -if 
+	fi
 	if [ "$TERMUX_ARCH" == "arm" ]; then
 		# valgrind doesn't like arm; armv7 works, though.
 		TERMUX_PKG_EXTRA_CONFIGURE_ARGS+=" --host=armv7-linux-androideabi"

packages/valgrind/coregrindmake.am.patch

@@ -0,0 +1,10 @@
+--- ../cache/valgrind-3.13.0/coregrind/Makefile.am	2017-05-31 15:14:31.000000000 +0000
++++ ./coregrind/Makefile.am	2018-08-19 00:35:33.162856194 +0000
+@@ -378,6 +378,7 @@
+ 	m_dispatch/dispatch-amd64-darwin.S \
+ 	m_dispatch/dispatch-x86-solaris.S \
+ 	m_dispatch/dispatch-amd64-solaris.S \
++	../aarch64-setjmp.S \
+ 	m_gdbserver/inferiors.c \
+ 	m_gdbserver/m_gdbserver.c \
+ 	m_gdbserver/regcache.c \

packages/valgrind/libcsetjmp.h.patch

@@ -0,0 +1,19 @@
+--- ../cache/valgrind-3.13.0/include/pub_tool_libcsetjmp.h	2017-05-31 15:14:14.000000000 +0000
++++ ./include/pub_tool_libcsetjmp.h	2018-08-17 23:14:23.768384982 +0000
+@@ -120,6 +120,16 @@
+ __attribute__((noreturn))
+ void  VG_MINIMAL_LONGJMP(VG_MINIMAL_JMP_BUF(_env));
+ 
++
++#elif defined(__ANDROID__) && defined(__aarch64__)
++
++/* Android clang/llvm has no __builtin_{setjmp,longjmp} for aarch64. */
++/* Use the same setjmp/longjmp functions for both gcc and clang.     */
++#define VG_MINIMAL_JMP_BUF(_name) jmp_buf _name
++#define VG_MINIMAL_SETJMP(_env)   ((UWord)(setjmp((_env))))
++#define VG_MINIMAL_LONGJMP(_env)  longjmp((_env),1)
++
++
+ #elif defined(VGP_mips64_linux)
+ 
+ #define VG_MINIMAL_JMP_BUF(_name)        ULong _name [168 / sizeof(ULong)]

packages/valgrind/memcheckmake.am.patch

@@ -0,0 +1,10 @@
+--- ../cache/valgrind-3.13.0/memcheck/Makefile.am	2017-05-31 15:14:03.000000000 +0000
++++ ./memcheck/Makefile.am	2018-08-19 00:20:49.488266235 +0000
+@@ -27,6 +27,7 @@
+ 	mc_main.c \
+ 	mc_translate.c \
+ 	mc_machine.c \
++	../aarch64-setjmp.S \
+ 	mc_errors.c
+ 
+ memcheck_@VGCONF_ARCH_PRI@_@VGCONF_OS@_SOURCES      = \